كيفية نسخ صيغة أسفل عمود بأكمله في جداول بيانات Google

أنت تعمل داخل جدول بيانات Google حيث تحتاج الصيغة إلى النسخ إلى الصف الأخير من الورقة. تحتاج أيضًا إلى إضافة الصيغة تلقائيًا عند إضافة صف جديد إلى ورقة Google.

هناك عدة طرق لحل هذه المشكلة.

انسخ الصيغة لأسفل في جداول بيانات Google

أسهل طريقة لنسخ الصيغ هي استخدام مقبض التعبئة في جداول بيانات Google. اكتب الصيغة في الصف الأول من جدول البيانات، ثم قم بتوجيه الماوس إلى الزاوية اليمنى السفلية من خلية الصيغة.

يتغير المؤشر إلى مقبض تعبئة (رمز زائد أسود) يمكنك سحبه إلى الصف الأخير من الورقة. لن يقوم مقبض التعبئة بنسخ الصيغ إلى كافة الخلايا المجاورة فحسب، بل سيقوم أيضًا بنسخ التنسيق المرئي.

إذا كنت بحاجة إلى نسخ الصيغ عبر الخلايا ولكن بدون أي تنسيق، فحدد الخلية التي تحتوي على التنسيق واضغط على Ctrl+C لنسخها إلى الحافظة. بعد ذلك، حدد النطاق الذي يجب تطبيق هذه الصيغة عليه، وانقر بزر الماوس الأيمن، واختر لصق خاص ولصق الصيغة فقط.

قم بتطبيق الصيغة على العمود بأكمله في جداول بيانات Google

إذا كان لديك مئات الصفوف في جدول بيانات Google وتريد تطبيق نفس الصيغة على جميع الصفوف في عمود معين، فهناك حل أكثر فعالية من النسخ واللصق – صيغ المصفوفة.

قم بتمييز الخلية الأولى في العمود واكتب الصيغة كما في السابق. ومع ذلك، بدلاً من تحديد خلية واحدة كمعلمة، سنقوم بتحديد العمود بأكمله باستخدام B2:B التدوين (ابدأ من الخلية B2 وانتقل إلى الصف الأخير من العمود B).

ثم اضغط على Ctrl+Shift+Enter، أو Cmd+Shift+Enter على نظام Mac، وستقوم جداول بيانات Google تلقائيًا بإحاطة الصيغة الخاصة بك بـ صيغة صفيف وظيفة.

وبالتالي، يمكننا تطبيق الصيغة على العمود بأكمله في جدول البيانات بخلية واحدة فقط. تعد صيغ الصفيف أكثر كفاءة لأنها تعالج مجموعة من الصفوف دفعة واحدة. كما أنها أسهل في الصيانة حيث أنك تحتاج فقط إلى تعديل خلية واحدة لتحرير الصيغة.

إحدى المشكلات التي ربما لاحظتها في الصيغ المذكورة أعلاه هي أنها تنطبق على كل صف في العمود حيث تريد فقط إضافة صيغ إلى الصفوف التي تحتوي على بيانات وتخطي الصفوف الفارغة.

يمكن القيام بذلك عن طريق إضافة IF إلى ARRAYFORMULA الخاص بنا بحيث لا يتم تطبيق الصيغة على أي من الصفوف الفارغة.

يقدم جدول بيانات Google وظيفتين للمساعدة في اختبار ما إذا كانت الخلية فارغة أم الآن.

• ISBLANK(A1) – إرجاع TRUE إذا كانت الخلية المشار إليها فارغة.
• LEN(A1) <> 0 – إرجاع TRUE إذا لم تكن الخلية المشار إليها فارغة، وإرجاع FALSE بخلاف ذلك

وبالتالي فإن صيغ الصفيف المعدلة الخاصة بنا ستكون كما يلي:

باستخدام ISBLANK (مرجع الخلية):

هناك عدة طرق أخرى لاختبار ما إذا كانت الخلية فارغة أم لا:

=ArrayFormula(IF(ISBLANK(B2:B), "", ROUND(B2:B*18%, 2)))
=ArrayFormula(IF(LEN(B2:B)<>0, ROUND(B2:B*18%, 2), ""))
=ArrayFormula(IF(B2:B="", "", ROUND(B2:B*18%, 2)))

استخدم صيغ الصفيف داخل رؤوس الأعمدة

في الأمثلة السابقة لدينا، نص عناوين الأعمدة (مثل ضريبة, المبلغ الإجمالي) تمت تعبئتها مسبقًا وتمت إضافة الصيغ فقط إلى الصف الأول من مجموعة البيانات.

يمكننا تحسين صيغتنا بشكل أكبر بحيث يمكن تطبيقها على رأس العمود نفسه. إذا كان فهرس الصف الحالي هو 1، ويتم حسابه باستخدام الدالة ROW()، فستقوم الصيغة بإخراج عنوان العمود وإلا فإنها تنفذ العملية الحسابية باستخدام الصيغة.

=ArrayFormula(IF(ROW(B:B)=1,"Tax",IF(ISBLANK(B:B),"",ROUND(B:B*18%, 2))))

تعبئة الصيغ تلقائيًا في عمليات إرسال نماذج Google

تعد وظائف ARRAYFORMULA مفيدة بشكل خاص لنماذج Google عندما يتم حفظ استجابات النموذج داخل ورقة Google. لا يمكنك إجراء حسابات مباشرة داخل نماذج Google ولكن يمكن إجراؤها داخل جدول البيانات الذي يجمع الردود.

يمكنك إنشاء أعمدة جديدة داخل جدول بيانات Google وتطبيق ARRAYFORMULA على الصف الأول من الأعمدة المضافة.

عند تلقي نموذج إرسال جديد، ستتم إضافة صف جديد إلى ورقة Google وسيتم استنساخ الصيغ وتطبيقها تلقائيًا على الصفوف الجديدة دون الحاجة إلى نسخ ولصق الأشياء.

راجع أيضًا: تحويل استجابة نموذج Google إلى مستندات PDF

كيفية استخدام VLOOKUP داخل ARRAYFORMULA

يمكنك دمج ARRAYFORMULA مع VLOOKUP لإجراء بحث سريع عبر عمود بأكمله.

لنفترض أن لديك ورقة “الفواكه” التي تسرد أسماء الفواكه في العمود “أ” والأسعار المقابلة في العمود “ب”. تحتوي الورقة الثانية “الطلبات” على أسماء الفاكهة في العمود “أ”، والكمية في العمود “ب”، ومن المفترض أن تقوم بحساب الطلب المبلغ في العمود C

=ArrayFormula(
  IF(ROW(A:A)=1,
  "Total",
  IF(NOT(ISBLANK(A:A)), VLOOKUP(A:A, Fruits!A2:B6, 2, FALSE) * B:B, "")))

باللغة الإنجليزية البسيطة، إذا كان صف الخلية الحالية هو 1، فقم بإخراج عنوان العمود بنص عادي. إذا كان الصف أكبر من 1 والعمود A في الصف الحالي ليس فارغًا، فقم بإجراء VLOOKUP لجلب سعر العنصر من ورقة Fruits. ثم اضرب هذا السعر بالكمية الموجودة في الخلية B وأخرج القيمة في الخلية C.

إذا كان نطاق VLOOKUP الخاص بك موجودًا في جدول بيانات Google آخر، فاستخدم IMPORTRANGE() تعمل بمعرف ورقة Google الأخرى.

يرجى ملاحظة أنه قد يتعين عليك استخدام الفواصل المنقوطة في صيغ جدول البيانات بدلاً من الفواصل لبعض اللغات.